User Automation Blog: Add Sender to Address Book and Reply

Add Sender to Address Book and Reply

When I posted the FAQ concerning my transition from Apple, it included a way for people interested in user automation to receive future communications from me about the topic. To my delight and surprise, I received requests (via email) from hundreds of folks from around the world.

Replying to a large volume of messages can be challenging, as these steps are required for each of the messages:

Figure out who sent the message. It’s not always obvious. Many people do not include their names in the sender part of the message. Some do, like: “Johnny Appleseed <john@appleseed.com>” but sometimes all you get for the sender address is: “bbq@hungryman.com”. Occasionally, the body of the message may contain more information, such as their first or full name. You have to carefully examine the sender data from the message.
Create a new contact card for the sender. In order keep track of each requester, I created a new card containing the sender’s information (name and email address) in the Contacts app, and then added the new card to a group named: “Newsletter”
Generate a confirmation message. My response message had to at least attempt to greet the requester by their first name (I used “Greetings” when no name was available). Sometimes the subscription requests contained personal comments or questions, so I would often alter the response in the outgoing message.
Send the message. This is something you don’t want to automate. Instead, it is wise to read and check the response message to make sure everything is as you want, and then click the Send button in Mail message window.

So what I came up with is an AppleScript script, saved to the Script Menu in Mail, and run individually after selecting each requester message, one-at-a-time. It turns out that the script is a great way to process a large number of individual emails, while retaining the ability read and respond to those requesters who added personal comments and questions.

All-in-all, responding to each of the requests took three days to complete, but was it very informative and never tedious, all thanks to the User Automation support in Mail and Contacts.

I don’t know if you’ll ever be in the same situation, but perhaps there are some ideas and tools you can use from this script:

Add Sender to Address Book and Reply

Open in Script Editor

use framework "Foundation"

use scripting additions

set messageBody to "Thank you for your interest and support. You’ve been added to my newsletter list. Should you ever wish to stop receiving communications from me, just send me another email!" & return & return & "Cheers," & return & return & "Your Name Here" & return & "Twitter: "

tell application id "com.apple.AddressBook"

if not (exists group "Newsletter") then

make new group with properties {name:"Newsletter"}

end if

set targetGroup to group "Newsletter"

end tell

tell application id "com.apple.mail"

activate

try

if (count of message viewers) is 0 then

error "No message viewer is open."

end if

set theseMessages to (get selected messages of the front message viewer)

if theseMessages is missing value then

error "No message is selected."

end if

-- Process multiple messages although likely used for one message at a time

set messageCount to the count of theseMessages

repeat with i from 1 to the messageCount

set thisMessage to item i of theseMessages

set messageSenderData to sender of thisMessage

(*Johnny Appleseed <john@appleseed.com>*)

copy my extractSenderDataFromSenderObject(messageSenderData) to {senderName, emailAddress}

if the (count of words of senderName) is not 1 then

set greetingName to the first word of senderName

set firstName to first word of senderName

set lastName to last word of senderName

else

set greetingName to senderName

set firstName to senderName

set lastName to ""

end if

set newMessage to reply thisMessage with opening window and reply to all

set content of newMessage to greetingName & ", " & return & return & messageBody

-- The Contacts application

tell application id "com.apple.AddressBook"

activate

set aPerson to make new person with properties {first name:firstName, last name:lastName}

tell aPerson

make new email with properties {label:"work", value:emailAddress}

end tell

-- to set changes, the database must be saved

save

add aPerson to targetGroup

save

if i is messageCount then

-- OPTIONAL: to assist with editing, select the new person in the Contacts app

set selection to {aPerson}

end if

end tell

end repeat

on error errorMsg number errorNum

activate

display alert (errorNum as string) message errorMsg

end try

end tell

on extractSenderDataFromSenderObject(messageSenderData)

set x to the offset of "<" in messageSenderData

if x is 0 then -- no name/address combo

set emailAddress to messageSenderData

set z to offset of "@" in emailAddress

if z is 0 then

return {emailAddress, emailAddress}

else

set senderName to text 1 thru (z - 1) of emailAddress

return {senderName, emailAddress}

end if

else

set y to the offset of ">" in messageSenderData

if y is 0 then

set senderName to messageSenderData

else

if x is 1 then

set senderName to "unknown"

else

set senderName to text 1 thru (x - 1) of messageSenderData

set senderName to my trimWhiteSpaceAroundString(senderName)

end if

set emailAddress to text from (x + 1) to (y - 1) of messageSenderData

return {senderName, emailAddress}

end extractSenderDataFromSenderObject

on trimWhiteSpaceAroundString(thisString)

set theString to current application's NSString's stringWithString:thisString

set theWhiteSet to current application's NSCharacterSet's whitespaceAndNewlineCharacterSet()

set theString to theString's stringByTrimmingCharactersInSet:theWhiteSet

return theString as text

end trimWhiteSpaceAroundString

DISCLAIMER

Mention of third-party websites and products is for informational purposes only and constitutes neither an endorsement nor a recommendation. USERAUTOMATION.COM assumes no responsibility with regard to the selection, performance or use of information or products found at third-party websites. USERAUTOMATION.COM provides this only as a convenience to our users. USERAUTOMATION.COM has not tested the information found on these sites and makes no representations regarding its accuracy or reliability. There are risks inherent in the use of any information or products found on the Internet, and USERAUTOMATION.COM assumes no responsibility in this regard. Please understand that a third-party site is independent from USERAUTOMATION.COM and that USERAUTOMATION.COM has no control over the content on that website. Please contact the vendor for additional information.